// Porte support modulable et vissable
//
//	(C) 2016 E.Chamouard
//	(Libre de droits pour utilisation non commerciale et à vos propres risques)
//

// Objectif : tenir la bobine de filament sur le cadre de la Prusa

// Utilise cette très bonne bibliothèque pour les pins :
//		Auteur : "tbuser"
//		Lien : 	www.thingiverse.com/thing:10541
include <..\lib\pins.scad>

// Enlever le commentaire pour générer l'objet choisi
//generate_wheel_old();
generate_wheel_new();
//generate_support_left();
//generate_support_right();

module generate_support_left()
{
	tolerance=0.3;

	difference()
	{
		union()
		{
			// Equerre de support
			translate([-35, -45, 0])cube([35, 90, 5]);
			translate([-5, -45, 0])cube([5, 90, 30]);

			// Les points d'attache
			translate([-35, -45, 0])cube([35, 20, 15]);
			translate([-35, 25, 0])cube([35, 20, 15]);

			// Levre pour le haut du cadre de la Prusa
			translate([0, -45, 0])
				intersection()
				{
					cube([5, 5, 30]);
					rotate([0, 0, 45])cube([10, 10, 30]);		
				}

			// Jambe pour s'appuyer sur le cadre
			translate([0, -33.5, 0])cube([45.5, 5, 30]);
			translate([40.5, -39.5, 0])cube([5, 6, 30]);

			// Renfort
			translate([0, -28.5, 0])
				intersection()
				{
					cube([45.5, 73.5, 5]);
					rotate([0, 0, 31.8])translate([0, -40, 0])cube([38.7, 200, 5]);
				}
		}
		union()
		{
			// Trous de fixation des roues
			translate([-25, 35, 15]) rotate([0, 180, 0]) pinhole(h=10, t=tolerance);
			translate([-25, -35, 15]) rotate([0, 180, 0]) pinhole(h=10, t=tolerance);
		}
	}
}

module generate_support_right()
{
	mirror([1, 0, 0])generate_support_left();
}

module generate_wheel_old() 
{
	cylinder(h=2, r=12);
	translate([0, 0, 2])cylinder(h=3, r1=12, r2=8);
	translate([0, 0, 5])cylinder(h=5, r=8);
	translate([0, 0, 10])cylinder(h=5, r1=8, r2=10);
	translate([0, 0, 15])pintack(h=10, br=10);
}

module generate_wheel_new() 
{
	translate([0, +20, 0])
		union()
		{
			cylinder(h=2, r=15);
			translate([0, 0, 2])cylinder(h=3, r1=15, r2=10);
			translate([0, 0, 5])cylinder(h=8, r=10);
			translate([0, 0, 10])cylinder(h=2, r=8);
			translate([0, 0, 13])pintack(h=10, br=8, bh=3);
		}
	translate([0, -20, 0])
		difference()
		{
		union()
			{
				cylinder(h=2, r=15);
				translate([0, 0, 2])cylinder(h=3, r1=15, r2=10);
			}
		union()
			{
				translate([0, 0, -.01])cylinder(h=2.02, r=8.5);
				translate([0, 0, 1.99])cylinder(h=3.02, r=10.5);
			}
		}
}