// Porte support modulable et vissable
//
//	(C) 2015 E.Chamouard
//	(Libre de droits pour utilisation non commerciale et à vos propres risques)
//

// Objectif : pouvoir accrocher un support standardisé sur une surface verticale
//
// On définit :
//		- la taille du support à soutenir, 
//		- les différentes épaisseur des murs du porte support,
//		- le jeu nécessaire pour que ça puisse s'introduire facilement,
//		- la taille des vis de fixation et leur ecartement.

// Parametres
hsupport=30;			// Hauteur du support
lsupport=70;			// Largeur du support
esupport=5;			// Epaisseur du support

esocle=10;			// Epaisseur du porte support (partie mur)
lmurlat=5;			// Largeur des mur latéraux du porte support
hmurbas=5;			// Hauteur du mur d'en bas du porte support

lmursur=5;			// Largeur de recouvrement des murs lateraux
hmursur=5;			// Hauteur de recouvrement du mur d'an bas
emursur=5;			// Epaisseur des murs de recouvrement

ljeu=1.0;				// Jeu lateral
hjeu=1.0;				// Jeu en hauteur
ejeu=1.0;				// Jeu d'épaisseur

d=4;						// Diametre de la vis
dt=8;					// Diametre de la tete de vis
ht=5;					// Hauteur de la tete de vis

ecvis=50;				// Ecartement entre les vis

use <lib/m_vis.scad>;

difference()
{
	translate([-(lsupport+2*lmurlat+ljeu)/2, -esupport-ejeu-emursur, -hmurbas-hjeu])
		cube([lsupport+2*lmurlat+ljeu, 
			esupport+esocle+ejeu+emursur, 
			hsupport+hmurbas+hjeu], center=false);
	union()
	{
		translate([-(lsupport+ljeu)/2, -esupport-ejeu, 0])
			cube([lsupport+ljeu, 
				esupport+ejeu, 
				hsupport+0.01], centre=false);
		translate([-(lsupport-2*lmursur)/2, -esupport-emursur-ejeu-0.01, hmursur])
			cube([lsupport-2*lmursur, 
				esupport+emursur+ejeu+0.01, 
				hsupport+0.01], centre=false);
		vis_fraisee(lg=esocle+5, d=d, dt=dt, lt=ht, dir=[0, 1, 0], pos=[-ecvis/2, 0, hsupport/2], ep=.1);
		vis_fraisee(lg=esocle+5, d=d, dt=dt, lt=ht, dir=[0, 1, 0], pos=[ecvis/2, 0, hsupport/2], ep=.1);
	}
}