//	m_objets.scad
//
//	Bibliothèque pour ecrire plus facilement des objets
//
//	(C) 2021-2024 E.Chamouard
//	(Libre de droits pour utilisation non commerciale et à vos propres risques)
//

//	Utilisation :
//		Inclure la biliothèque dans votre fichier, par exemple :
//			use <lib/m_objets.scad>;

//
//	Objets disponnibles :

//		objet_cylindre(h=20, d=10, px=0, py=0, pz=0);
//			Avec (tout en mm, tous les paramètres étant optionnels):
//				h la hauteur du cylindre (vertical)
//				d le diamètre du cylindre
//				px, py, pz : position où repose le cylindre

//    objet_parallelepipede(dx=20, dy=40, dz=40, px=0, py=0, pz=0)
//			Avec (tout en mm, tous les paramètres étant optionnels):
//				dx, dy, dz, les 3 dimensions du parallelepipede
//				px, py, pz : position du coin du objet_parallelepipede
//                  (plus petit x, plus petit y, plus petit z 
//                  si dx, dy, dz positifs)

//	  objet_toit(x1=0, y1=0, x2=20, y2=40, zb=0, zh=20)
//			Avec (tout en mm, tous les paramètres étant optionnels) :
//				x1, y1, x2, y2 dessinant un rectangle horisontal
//        x1 plus petit x et y1 plus petit y
//				zb et zh les points bas et haut du toit
//				le toit est le long de l'axe y

//	  objet_tetraedre(x1=0, y1=0, x2=20, y2=0, x3=0, y3=20, x4=10, y4=10, 
//        zb=0, zh=20)
//			Avec (tout en mm, tous les paramètres étant optionnels) :
//				x1, y1, x2, y2, x3, y3 dessinent un triangle horisontal
//        x4, y4 est le sommet
//        x1 plus petit x et y1 plus petit y
//				zb et zh les points bas et haut du tetraedre

//    objet_prisme_triangulaire(x1=0, y1=0, x2=10, y2=0, x3=10, y3=10, zb=0, 
//          zh=10)
//			Avec (tout en mm, tous les paramètres étant optionnels):
//				x1, y1, x2,... y3 le triangle de base du prisme
//              les trois points doivent être en sens trigonométrique (horaire 
//              si on regardait le prisme du dessous)
//				zb et zh les points bas et haut du prisme

//    objet_trapeze_mur(x1=0, z1=0, x2=20, z2=0, x3=15, z3=20, x4=2, z4=20, yl=30, yp=10)
//			Avec (tout en mm, tous les paramètres étant optionnels):
//				x1, z1, x2,... z4 dessinent le trapèrze dans un plan vertical
//        yp et yl les points proches et loin du trapeze (yp<yl)

//    objet_trapeze_sol(x1=0, y1=0, x2=20, y2=0, x3=18, y3=20, x4=5, y4=20, zb=0, zh=10)
//			Avec (tout en mm, tous les paramètres étant optionnels):
//				x1, y1, x2,... z4 dessinent le trapèrze dans un plan horisontal
//        zb et zh les points bas et haut du trapèze (zb<zh) 


//	Exemples : Enlever un des commentaires dans les lignes ci-dessous
//objet_cylindre(h=40, d=20, px=10, py=10, pz=10);
//objet_parallelepipede(dx=20, dy=40, dz=40, px=10, py=10, pz=10);
//objet_toit(x1=0, y1=0, x2=20, y2=40, zb=0, zh=20);
//objet_tetraedre(x1=0, y1=0, x2=20, y2=0, x3=0, y3=20, x4=30, y4=10, zb=0, zh=20);
//objet_prisme_triangulaire(x1=0, y1=0, x2=10, y2=0, x3=10, y3=10, zb=20, zh=30);
//objet_trapeze_mur(x1=0, z1=0, x2=20, z2=0, x3=15, z3=20, x4=2, z4=20, yl=30, yp=10);
//objet_trapeze_sol(x1=0, y1=0, x2=20, y2=0, x3=18, y3=20, x4=5, y4=20, zb=0, zh=10);
//m_object_test();

module m_object_test()
{
  objet_cylindre(h=40, d=20, px=-40, py=-40, pz=0);
  objet_parallelepipede(dx=20, dy=40, dz=40, px=-40, py=-20, pz=0);
  objet_toit(x1=0, y1=-40, x2=20, y2=0, zb=0, zh=20);
  objet_tetraedre(x1=40, y1=-20, x2=60, y2=-10, x3=40, y3=0, x4=50, y4=-10, zb=0, zh=20);
  objet_prisme_triangulaire(x1=40, y1=-40, x2=50, y2=-40, x3=50, y3=-30, zb=0, zh=30);
  objet_trapeze_mur(x1=0, z1=0, x2=20, z2=0, x3=15, z3=20, x4=2, z4=20, yl=30, yp=10);
  objet_trapeze_sol(x1=40, y1=10, x2=60, y2=10, x3=58, y3=30, x4=45, y4=30, zb=0, zh=10);
}


module objet_cylindre(h=20, d=10, px=0, py=0, pz=0, fn=18)
{
	translate([px, py, pz])cylinder(h=h, d=d, center=false, $fn=fn);
}

module objet_parallelepipede(dx=10, dy=10, dz=10, px=0, py=0, pz=0)
{
    translate([px, py, pz])cube([dx, dy, dz]);
}

module objet_toit(x1=0, y1=0, x2=20, y2=40, zb=0, zh=20)
{
    ToitPoints=[
        [x1, y1, zb],   //0
        [x2, y1, zb],   //1
        [x2, y2, zb],   //2
        [x1, y2, zb],   //3
        [(x1+x2)/2, y1, zh],   //4
        [(x1+x2)/2, y2, zh]];  //5
  
    ToitFaces=[
        [0,1,2,3],      // dessous
        [1,4,5,2],      // toit
        [0,3,5,4],      // toit
        [0,4,1],        // cote
        [2,5,3]];       // cote
    polyhedron(ToitPoints, ToitFaces);
}

module objet_tetraedre(x1=0, y1=0, x2=20, y2=0, x3=0, y3=20, x4=10, y4=10, zb=0, zh=20)
{
    TetraedrePoints=[
        [x1, y1, zb],   //0
        [x2, y2, zb],   //1
        [x3, y3, zb],   //2
        [x4, y4, zh]];  //3
  
    TetraedreFaces=[
        [0,1,2],        // dessous
        [0,3,1],        // cote
        [1,3,2],        // cote
        [0,2,3]];       // cote
    polyhedron(TetraedrePoints, TetraedreFaces);
}

module objet_prisme_triangulaire(x1=0, y1=0, x2=10, y2=0, x3=10, y3=10, zb=0, zh=10)
{
    PrismePoints=[
        [x1, y1, zb],   //0
        [x2, y2, zb],   //1
        [x3, y3, zb],   //2
        [x1, y1, zh],   //3
        [x2, y2, zh],   //4
        [x3, y3, zh]];  //5
  
    PrismeFaces=[
        [0,1,2],        // dessous
        [0,3,4,1],      // cote
        [1,4,5,2],      // cote
        [2,5,3,0],      // cote
        [3,5,4]];       // dessus
    polyhedron(PrismePoints, PrismeFaces);
}

module objet_trapeze_mur(x1=0, z1=0, x2=20, z2=0, x3=15, z3=20, x4=2, z4=20, yl=30, yp=10)
{
    TrapezePoints=[
        [x1, yp, z1],   //0
        [x2, yp, z2],   //1
        [x3, yp, z3],   //2
        [x4, yp, z4],   //3
        [x1, yl, z1],   //4
        [x2, yl, z2],   //5
        [x3, yl, z3],   //6
        [x4, yl, z4]];  //7
  
    TrapezeFaces=[
        [0,3,2,1],      // devant
        [4,5,6,7],      // derriere
        [0,4,7,3],      // côté gauche
        [1,2,6,5],      // côté droit
        [3,7,6,2],      // dessus
        [0,1,5,4]];     // dessous
    polyhedron(TrapezePoints, TrapezeFaces);
}

module objet_trapeze_sol(x1=0, y1=0, x2=20, y2=0, x3=18, y3=20, x4=5, y4=20, zb=0, zh=10)
{
    TrapezePoints=[
        [x1, y1, zb],   //0
        [x2, y2, zb],   //1
        [x3, y3, zb],   //2
        [x4, y4, zb],   //3
        [x1, y1, zh],   //4
        [x2, y2, zh],   //5
        [x3, y3, zh],   //6
        [x4, y4, zh]];  //7
  
    TrapezeFaces=[
        [0,4,5,1],      // devant
        [2,6,7,3],      // derriere
        [0,3,7,4],      // côté gauche
        [1,5,6,2],      // côté droit
        [4,7,6,5],      // dessus
        [0,1,2,3]];     // dessous
    polyhedron(TrapezePoints, TrapezeFaces);
}